TraceSDWrite

概略

リングバッファからデータを読み出して書込みバッファ（バイト配列）に書込みデータを格納します
書込みデータをセットできたらFileWite命令でSDカードに書込みします

ソース

TraceSDWriteの一部 ST部分

IF TraceData.Count > 0 THEN
	// 最大処理行数ループ
	FOR RowCnt := 0 TO 	99 BY 1 DO
		RingbufGet(TraceData, Data);		// リングバッファから読出し
		IF Data.DateTime > DT#1970-01-01-00:00:00.0 THEN	// 区切り行か？
			//データをバイト配列に格納
			Pos := StringToAry(DateToString(DT_TO_DATE(Data.DateTime)), WriteBuf[Pos]) + Pos;
			WriteBuf[Pos] := BYTE#16#20;	Pos := Pos + 1;
			Pos := StringToAry(MID(DtToString(Data.DateTime), 15, 12), WriteBuf[Pos]) + Pos;
			WriteBuf[Pos] := BYTE#16#2C;	Pos := Pos + 1;

			FOR cnt := 0 TO BitDataSize - 1 BY 1 DO
				IF Data.B[cnt] THEN
					WriteBuf[Pos] := BYTE#16#31;	Pos := Pos + 1;
				ELSE
					WriteBuf[Pos] := BYTE#16#30;	Pos := Pos + 1;
				END_IF;
				WriteBuf[Pos] := BYTE#16#2C;	Pos := Pos + 1;
			END_FOR;

			FOR cnt := 0 TO DIntDataSize - 2 BY 1 DO
				Pos := StringToAry(DINT_TO_STRING(Data.DI[cnt]), WriteBuf[Pos]) + Pos;
				WriteBuf[Pos] := BYTE#16#2C;	Pos := Pos + 1;
			END_FOR;

			Pos := StringToAry(DINT_TO_STRING(Data.DI[cnt]), WriteBuf[Pos]) + Pos;
			WriteBuf[Pos] := BYTE#16#0D;		Pos := Pos + 1;
			WriteBuf[Pos] := BYTE#16#0A;		Pos := Pos + 1;

		ELSE
			RecEnd := TRUE;		// 区切り行ならファイルを切り替えるためループを抜ける
			EXIT;
		END_IF;

		IF TraceData.Count = 0 THEN EXIT;	END_IF;		// リングバッファが空になれば抜ける
		IF Pos > UINT#60000 THEN	EXIT;	END_IF;		// 書込みバイト数が60000byteを超えたら抜ける

	END_FOR;

END_IF;

リングバッファからRingBufGetでデータを取り出し、句切り行（空白）でなければバイト配列WriteBufに書込んでいきます
書込み位置はPosで制御し、構造体のメンバのデータをバイト配列に変換した後に区切り文字のカンマ(0x2C)を挿入します
BOOL型はTrueを"1"(0x31)で、Falseを"0"(0x30)に変換し、数値型はDINT_TO_STRINGなどで数値に変換した後にStringToAryでバイト配列に変換します
実数型はLrealToFormatStringなどで文字列に変換した後にStringToAryでバイト配列に変換します
一行分の変換が終われば改行コードCrLf(0x0d,0x0a)を挿入します
データ型によって命令語を変更してください

リングバッファのカウントが0でなければ再度リングバッファからデータを取り出して同じ処理を行います
もし、書込み位置Posが60000を超えればバッファが一杯になったとして一旦変換処理を抜けてファイル書き出し処理に移行します

１スキャンで変換する行数は最大処理行数RowCntで調整します
大きくするとスキャンタイムが伸びますが一度に書き込むバイト数が増えるため、書込み時間は短くなることが期待できます
定周期タスクで実行する理由はここにあります
定周期タスクのタスク周期と最大処理行数のループ数を調整して最適な処理時間になるように調整してください

TraceSDWrite

概略

ソース

この記事へのコメント